Na}{

File Content: `_timedatectl`

#compdef timedatectl
# SPDX-License-Identifier: LGPL-2.1-or-later

_timedatectl_set-timezone(){
    local -a _timezones
    _timezones=( ${(f)"$(_call_program timezones "${service}" list-timezones)"} )
    compadd "$_timezones[@]"
}

_timedatectl_set-time(){
    _message "YYYY-MM-DD HH:MM:SS"
}

_timedatectl_set-local-rtc(){
    local -a _options
    _options=(
        '0:Maintain RTC in universal time'
        '1:Maintain RTC in local time'
    )
    _describe options _options
}

_timedatectl_set-ntp(){
    local -a _options
    _options=(
        '0:Disable NTP based network time configuration'
        '1:Enable NTP based network time configuration'
    )
    _describe options _options
}

_timedatectl_command(){
    local -a _timedatectl_cmds
    _timedatectl_cmds=(
        'status:Show current time settings'
        'set-time:Set system time'
        'set-timezone:Set system timezone'
        'list-timezones:Show known timezones'
        'set-local-rtc:Control whether RTC is in local time'
        'set-ntp:Control whether NTP is enabled'
    )
    if (( CURRENT == 1 )); then
        _describe -t commands 'timedatectl command' _timedatectl_cmds
    else
        local curcontext="$curcontext"
        cmd="${${_timedatectl_cmds[(r)$words[1]:*]%%:*}}"
        if (( $#cmd )); then
            if (( $+functions[_timedatectl_$cmd] )); then
                _timedatectl_$cmd
            else
                _message "no more options"
            fi
        else
            _message "unknown timedatectl command: $words[1]"
        fi
    fi
}

_arguments -s \
    {-h,--help}'[Show this help]' \
    '--version[Show package version]' \
    '--adjust-system-clock[Adjust system clock when changing local RTC mode]' \
    '--no-pager[Do not pipe output into a pager]' \
    '--no-ask-password[Do not prompt for password]' \
    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
    '*::timedatectl commands:_timedatectl_command'

Name	Size	Permission
_bootctl	2450 bytes	0644
_busctl	9594 bytes	0644
_curl	15240 bytes	0644
_hostnamectl	2793 bytes	0644
_journalctl	7194 bytes	0644
_kernel-install	779 bytes	0644
_localectl	3773 bytes	0644
_loginctl	6397 bytes	0644
_networkctl	2159 bytes	0644
_resolvectl	3744 bytes	0644
_sd_hosts_or_user_at_host	128 bytes	0644
_sd_outputmodes	306 bytes	0644
_sd_unit_files	263 bytes	0644
_snap	1824 bytes	0644
_systemctl	19889 bytes	0644
_systemd	3848 bytes	0644
_systemd-analyze	4227 bytes	0644
_systemd-delta	633 bytes	0644
_systemd-inhibit	1179 bytes	0644
_systemd-path	285 bytes	0644
_systemd-run	4346 bytes	0644
_systemd-tmpfiles	744 bytes	0644
_timedatectl	2050 bytes	0644
_udevadm	6533 bytes	0644

File Content: _timedatectl

File Content: `_timedatectl`